RGBCube/serenity
1
Fork 0
mirror of https://github.com/RGBCube/serenity synced 2025-07-26 12:07:45 +00:00
Code Issues Activity Actions

Kernel: Use the C preprocessor to avoid two copies of the linker script

Browse source
This commit is contained in:
Gunnar Beutner 2021-07-20 10:40:09 +02:00 • committed by Andreas Kling
parent 56f952a5f2
commit 2019cf3289
3 changed files with 21 additions and 101 deletions
Download patch file Download diff file Expand all files Collapse all files

104
Kernel/linker.ld Normal file
View file

@ -0,0 +1,104 @@
#include <AK/Platform.h>
ENTRY(init)
#if ARCH(I386)
# define KERNEL_BASE 0xc0000000
#else
# define KERNEL_BASE 0x2000000000
#endif
KERNEL_VIRTUAL_BASE = KERNEL_BASE;
PHDRS
{
super_pages PT_LOAD ;
text PT_LOAD ;
data PT_LOAD ;
bss PT_LOAD ;
ksyms PT_LOAD ;
}
SECTIONS
{
. = KERNEL_VIRTUAL_BASE + 0x00200000;
start_of_kernel_image = .;
.super_pages ALIGN(4K) (NOLOAD) : AT (ADDR(.super_pages) - KERNEL_VIRTUAL_BASE)
{
*(.super_pages)
} :super_pages
.text ALIGN(4K) : AT (ADDR(.text) - KERNEL_VIRTUAL_BASE)
{
start_of_kernel_text = .;
start_of_safemem_text = .;
KEEP(*(.text.safemem))
end_of_safemem_text = .;
start_of_safemem_atomic_text = .;
KEEP(*(.text.safemem.atomic))
end_of_safemem_atomic_text = .;
*(.text*)
} :text
.unmap_after_init ALIGN(4K) : AT (ADDR(.unmap_after_init) - KERNEL_VIRTUAL_BASE)
{
start_of_unmap_after_init = .;
*(.unmap_after_init*);
end_of_unmap_after_init = .;
end_of_kernel_text = .;
} :text
.rodata ALIGN(4K) : AT (ADDR(.rodata) - KERNEL_VIRTUAL_BASE)
{
start_heap_ctors = .;
*libkernel_heap.a:*(.ctors)
end_heap_ctors = .;
start_ctors = .;
*(.ctors)
end_ctors = .;
*(.rodata*)
} :data
.data ALIGN(4K) : AT (ADDR(.data) - KERNEL_VIRTUAL_BASE)
{
start_of_kernel_data = .;
*(.data*)
end_of_kernel_data = .;
} :data
.ro_after_init ALIGN(4K) (NOLOAD) : AT(ADDR(.ro_after_init) - KERNEL_VIRTUAL_BASE)
{
start_of_ro_after_init = .;
*(.ro_after_init);
end_of_ro_after_init = .;
} :data
.bss ALIGN(4K) (NOLOAD) : AT (ADDR(.bss) - KERNEL_VIRTUAL_BASE)
{
start_of_kernel_bss = .;
*(page_tables)
*(COMMON)
*(.bss)
end_of_kernel_bss = .;
. = ALIGN(4K);
*(.heap)
} :bss
.ksyms ALIGN(4K) : AT (ADDR(.ksyms) - KERNEL_VIRTUAL_BASE)
{
start_of_kernel_ksyms = .;
*(.kernel_symbols)
end_of_kernel_ksyms = .;
} :ksyms
end_of_kernel_image = .;
}